COM實現過程 (轉)
您是第
713個瀏覽者
作者：吳劍明(foxnt)
前言
COM已經成為一個必需的東西了。在我們周圍，可以說處處充滿了COM - 如果你是在使用WINDOWS，並在其下面編寫程式的話。然而，無論你是用VC，還是使用DELPHI進行COM編程時，在大多數情況下，編程工具的IDE已經向你隱藏了COM的大部分實現過程，使得程式師根本不需要瞭解COM，只專心致志地寫其所關心的邏輯代碼。這就意味著，我們很少有機會，能夠揭開COM的神秘面紗，來看到它下面到底是什麼東西。這對於一個WINDOWS程式師來說，不能不是個遺憾。
因此，本文的宗旨，就是拋開現有的IDE提供的各種嚮導工具，引導大家從最基本的地方入手，完整地從一個空白的程式裏，建立起一個COM程式，從而達到能夠比較清晰地瞭解一個COM，到底是如何生成出來並實現在程式中。
本文假設，您是一個有COM編程經驗的DELPHI/VC程式師，並希望瞭解COM的基本實現過程。限於篇幅和時間，我們只討論進程內的COM（DLL）的實現，並引導大家親手建立起一個最簡單的COM程式。
COM是什麼？
COM有各種表現形式，可以是進程內，也可以是進程外；可以在本機調用，也可以遠端調用。記得國外有個研究COM的組織，他的主題就叫作：COM就是愛！ 這當然是外國人的幽默，他只是想說明，COM是個多麼重要的東西。那麼COM到底是個什麼東西呢？
很早以前，在我剛開始學習COM的時候，身邊就有些程式師告訴我：COM不是DLL，雖然它通常也是以DLL來作為副檔名的，可他完全與DLL完全不同。那麼，這種說法是否正確呢？我們來看看，要實現一個進程內的COM，到底需要經過哪些步驟，那麼，我們就能很清楚的知道答案了。
完成一個進程內的COM，通常需要以下幾步：
1. 建立一個DLL項目，並導出以下四個函數：
DllGetClassObject,
DllCanUnloadNow,
DllRegisterServer,
DllUnregisterServer;
2. 定義自定義的介面，同時必須實現Iunknown介面。
3. 建立GUID，以標識這個元件以及自定義的介面。
4. 在註冊表中註冊以標記這個DLL。
大家都看到了，在第一個步驟裏，需要建立一個DLL專案，那麼，是不是意味著，COM就是一個DLL呢？在這裏，我可以明確地告訴大家，從技術上講，一個進程內的COM完全可以被認為就是一個普通的DLL-動態連接庫！如果你拋棄常用的COM API，比如DELPHI中常用的：
CreateCOMObject()或者
CreateOLEObject()
那麼您完全可以直接採用載入普通DLL的方式來調用這個COM元件，比如說，您可以直接用LoadLibrary()函數來載入這個DLL，然後使用GetProcAddress來調用從這個DLL裏輸出的介面，從而完成各項操作。這是完全可行的。然而，我不得不告訴大家，把一個COM僅僅看成一個DLL，那是非常膚淺的看法 - DLL僅僅是一種表現形式而已。更重要的是，COM實現了一種規則。因此我們可以說：
l COM是一種包含了許多處理邏輯、符合了某種介面規範（如Iunknown規範）的DLL元件。
（注：如果沒有特別說明，我在本文裏所指的COM，都是指進程內的DLL形式的COM）
l COM實現了Iunknown介面。因此，任何只要符合Iunknown規範，實現了Iunknown介面的DLL元件，我們都可以把他看成是一個COM。
那麼，什麼是Iunknown介面呢？如何實現一個Iunknown介面呢？我們看看，在DELPHI中是如何定義一個Iunknown介面的：
IInterface = interface
['{00000000-0000-0000-C000-000000000046}']
function QueryInterface(const IID: TGUID; out Obj): HResult; stdcall;
function _AddRef: Integer; stdcall;
function _Release: Integer; stdcall;
end;
IUnknown = IInterface;
簡單一點看，我們直接這樣理解就行了：
IUnknown = interface
['{00000000-0000-0000-C000-000000000046}']
function QueryInterface(const IID: TGUID; out Obj): HResult; stdcall;
function _AddRef: Integer; stdcall;
function _Release: Integer; stdcall;
end;
在DELPHI裏，interface是編譯器所認識的一種類型。如果是在VC++中，Iunknown將被定義為一種結構（struct）。如果要實現一個Iunknown介面，我們必須用一個類來實現它，比如在DELPHI中，要實現Iunknown介面可以寫成為：
TMyCOMObject = class (Tobject, Iunknown)
……
end;
有心的讀者可能會立即問：這個Iunknown介面由Tobject來實現，那麼，可不可以是由其他類來實現呢？比如說用Tcomponent類來實現？答案是： 完全可以！！
例如，我們要實現一個自定義的介面IMyCOM，可以寫成這樣：
IMyCOMTest = interface(Iunknown);
TMyCOMTest = class(Tcomponent, IMyCOMTest)
…….
End;
這樣是完全可以的！因為COM關注的只是如何實現一個介面，至於程式師使用什麼類來實現，COM是不管的。
後面我們要實現一個COM的例子，而且我打算就用這個IMyCOMTest介面來做。所以我們把這個介面聲明成為例1，以便後面使用。
COM的產生
假如我們已經完成了一個COM，並且已經在系統中註冊了。那麼，一個用戶端需要來調用這個COM，這時，系統中發生了哪些事呢？
一般來說，以DELPHI為例，客戶程式使用CreateCOMObject或者CreateOLEObject調用COM元件時，會發生以下幾個步驟：
1. CreateCOMObject或者CreateOLEObject的動作。
我們看看這兩個函數都幹了些什麼：
function CreateComObject(const ClassID: TGUID): IUnknown;
begin
OleCheck(CoCreateInstance(ClassID, nil, CLSCTX_INPROC_SERVER or
CLSCTX_LOCAL_SERVER, IUnknown, Result));
end;
CreateOLEObject稍微複雜些：
function CreateOleObject(const ClassName: string): IDispatch;
var
ClassID: TCLSID;
begin
ClassID := ProgIDToClassID(ClassName);
OleCheck(CoCreateInstance(ClassID, nil, CLSCTX_INPROC_SERVER or
CLSCTX_LOCAL_SERVER, IDispatch, Result));
end;
看到了嗎？CreateOLEObject多了一個ProgIDToClassID函數。這意味著，如果我們要用CreateOLEObject來調用我們的COM元件，我們將要多一些步驟來編寫我們的COM。這個我將會在後面說明。現在，我們要關注的是CoCreateInstance API函數。
2. CoCreateInstance API函數將調用CoGetClassObject API，這個調用過程我們是看不到相關的代碼的，因為微軟已經把他封裝好了。而CoGetClassObject函數的作用是什麼呢？它將調用LoadLibrary來尋找我們指定的COM元件（DLL），然後使用GetProcAddress 來尋找元件的入口函數 - 還記得我們上面說過的那四個被導出的函數嗎？對，其中的DllGetClassObject 函數就在這裏將被調用。該函數的原形在DELPHI中是：
function DllGetClassObject(const CLSID, IID: TGUID; var Obj): HResult;
其中第三個參數：Obj ，將向我們返回COM中的定義的介面。但是，要注意，這個介面並不是我們自定義的介面，而是向我們返回了一個被成為是“類工廠”介面的IclassFactory的介面。當我們獲得類工廠介面後，就可以獲得我們所需要的、那個我們自定義的介面了。看看IclassFactory 的介面聲明：
IClassFactory = interface(IUnknown)
['{00000001-0000-0000-C000-000000000046}']
function CreateInstance(const unkOuter: IUnknown; const iid: TIID;
out obj): HResult; stdcall;
function LockServer(fLock: BOOL): HResult; stdcall;
end;
看到那個CreateInstance 的方法了嗎？對了，它的第三個參數 obj 將向我們返回那個我們定義的介面，比如是我們的IMyCOMTest介面（例1）。這樣，我們就可以調用我們自定義的介面方法了。
以上的眾多步驟看起來有點讓人迷惑。那麼我們就用一個簡單的流程來描繪我們剛才所發生的步驟。不要被那些步驟嚇倒，其實他們是非常簡單的。
l CreateCOMObject --à CoCreateInstance。 CoCreateInstance 在註冊表中查找COM的註冊資訊。
l CoCreateInstance -à CoGetClassObject 。註冊資訊被交給CoGetClassObject。這時候CoGetClassObject將知道COM元件在磁片上的位置。
l CoGetClassObject -à LoadLibrary 。LoadLibrary 將尋找COM DLL的入口，然後GetProcAddress調用其輸出函數DllGetClassObject
l DllGetClassObject 的輸出參數將向我們返回“類工廠”介面IClassFactory。
l IclassFactory --à CreateInstance 。CreateInstance方法建立其我們實現介面的類。該類將調用自身的QueryInterface 方法，查看用戶指定的介面是否被自己實現，如果實現了，則向返回自定義的介面。
l 調用結束後，COM客戶將調用COM的DLL輸出函數DllCanUnloadNow 。如果該函數返回S_OK，則釋放該元件。
實際的COM例子
下面我們來做一個實際的例子。包括如何建立一個COM Server和一個COM Client。
對於COM Server，我們將實現以下功能：
l 單線程，單客戶支援。
l 實現自定義的介面
l 能夠使用Regsvr32 在系統中註冊和反註冊。
l 能夠被DELPHI或者VC++程式調用。
我們只關注實現最基本的功能。當大家清楚整個流程後，自然就能寫出更高級的功能，比如多線程支援等。
下面，讓我們開始COM實現之旅。
COM Server程式
l 在DELPHI中，新建一個DLL工程。注意是DLL，而不是 Activex Library。並把工程名保存為MyCOM。然後依次建立兩個單元檔：
MyCOMServer 單元： 此單元描述了COM的邏輯實現
COMDef 單元： 此單元描述了COM的輸出函數定義。
l 在MyCOM單元裏，我們定義DLL的輸出函數，整個代碼：
library MyCOM;
uses
SysUtils,
Classes,
COMDef,
MyCOMServer in 'MyCOMServer.pas';
//在這裏導出四個函數。
exports
DllGetClassObject,
DllCanUnloadNow,
DllRegisterServer,
DllUnregisterServer;
{$R *.res}
begin
end.
先做好定義，不要考慮他們是如何實現的。這個在後面我會做詳細解說。在這裏我先說明這四個函數的作用：
DllGetClassObject ： 返回類工廠介面。
DllCanUnloadNow ： 告訴用戶端該COM是否可以被正常卸載。
DllRegisterServer ： 向系統註冊COM元件資訊。Regsvr32.exe 就是調用這個函數來進行註冊的。
DllUnregisterServer ：從系統中反註冊一個COM。Regsvr32.exe 就是調用這個函數來進行反註冊的。
l 現在為我們的COM定義GUID。注意，在一個COM元件裏，有三種GUID：
CLASS_xx 類型的GUID，是用來標識COM元件的。
IID_xx類型的GUID，是用來標識一個介面的。可以有多個。
LIBID_xx類型的GUID，是用來標識一個TypeLib的。關於如何實現一個TypeLib，我會在COM實現過程（2）中會講到。在這裏先略過。
現在，我們定義我們的COM組件的GUID，在COMDef單元裏加入的代碼為：
const
Class_MyCOM: TGUID = '{CE38847E-A386-4753-89F1-34BE80042107}';
LIBID_MyCOM: TGUID = '{C2387E2A-0F08-442E-8947-D1AB36A9BDD0}';
l 開始定義我們的介面。我們採用例一所定義的介面，在MyCOMServer單元裏加入代碼：
IMyCOMTest = interface(IUnknown)
['{D1C4A022-7F6F-42F0-A9B0-4A91703EB124}']
function msg: integer;stdcall;
end;
注意，在這裏，我們為IMyCOMTest 定義了一個IID類型的GUID，它唯一表示我們的介面。同時我們定義了一個方法 msg ，它向我們返回一個整數值。
定義了介面，當然要實現它：
TMyCOMServer = class(TObject, IMyCOMTest)
protected
FLock: integer;
function QueryInterface(const IID: TGUID; out Obj): HResult; stdcall;
function _AddRef: Integer; stdcall;
function _Release: Integer; stdcall;
public
Constructor Create;
function msg: integer;stdcall;
end;
現在，我們一個個的來說明並實現TMyCOMServer 的幾個方法。
_AddRef 方法：
該方法用於增加一個COM的計數器。我們知道COM Server是需要支援多客戶調用的，在COM中每實現一次調用，就必須進行計數。如果COM的計數>0 ，則COM繼續生存。否則，該COM介面實例就必須被登出。
_Release 方法：
該方法和_AddRef方法相反，用於減少一個計數，當計數為0，則登出該介面。
QueryInterface 方法：
該方法用於查詢一個介面是否存在，如果存在則在輸出參數裏返回該介面指標。
為實現這幾個方法，所添加的代碼如下：
function TMyCOMServer._AddRef: Integer;
begin
Inc(FLock);
end;
function TMyCOMServer._Release: Integer;
begin
Dec(FLock);
if FLock = 0 then
Free;
end;
function TMyCOMServer.QueryInterface(const IID: TGUID; out Obj): HResult;
begin
//在類工廠中實現的一個MC介面，在這裏返回。由於我們只有一個介面，所以那個IID參數沒有用。當然，如果我們實現了多個介面，就需要維護一個陣列，用個CASE語句，根據不同的IID，來返回不同的介面。
Pointer(Obj) := Pointer(MC);
Result := S_OK;
end;
其中，MC是一個IMyCOMTest 介面，是個總體變數：
var
MC: IMyCOMTest;
CF: IClassFactory;
別忘了還有我們的構造器：
constructor TMyCOMServer.Create;
begin
Inc(FLock);
end;
在一開始就增加一個引用計數，使得COM計數大於1，這樣COM就不會自動銷毀。
然後去實現我們的介面方法：
function TMyCOMServer.msg: integer;
begin
result := 1978;
end;
該方法直接向我們返回一個整數值。
l 類工廠的實現
正如我前面所說的，一個類工廠必須去建立我們自定義的介面。在上面，我們定義了自定義的介面，並由類TMyCOMServer 去實現。那麼，現在我們還要做的是，實現類工廠，然後由類工廠建立一個TMyCOMServer 的介面實例。類工廠介面定義如下：
IClassFactory = interface(IUnknown)
['{00000001-0000-0000-C000-000000000046}']
function CreateInstance(const UnkOuter: IUnknown; const IID: TGUID;
out Obj): HResult; stdcall;
function LockServer(fLock: Boolean): HResult; stdcall;
end;
注意，IclassFactory是系統預先定義了的，在ACTIVEX單元有，所以不需要自己再去定義一次。我們只要去實現它就是：
TClassFactory = class(TObject, IClassFactory)
protected
FLock: integer;
function QueryInterface(const IID: TGUID; out Obj): HResult; stdcall;
function _AddRef: Integer; stdcall;
function _Release: Integer; stdcall;
public
Constructor Create;
function CreateInstance(const UnkOuter: IUnknown; const IID: TGUID;
out Obj): HResult; stdcall;
function LockServer(fLock: Boolean): HResult; stdcall;
end;
我們只關注CreateInstance 方法。LockServer 用於在多客戶調用COM時，鎖定COM，以免一個客戶退出時銷毀了COM，那麼其他客戶的調用將發生錯誤。但是我們在這裏只實現單客戶，所以不考慮這個函數，把他置空就是。
function TClassFactory.CreateInstance(const UnkOuter: IInterface;
const IID: TGUID; out Obj): HResult;
begin
//我們的自定義介面，就是在這裏被創建的。
MC := TMyCOMServer.Create;
Pointer(Obj) := Pointer(MC);
end;
function TClassFactory.LockServer(fLock: Boolean): HResult;
begin
end;
同樣的，TclassFactory也必須實現引用計數，因為它也實現了Iunknown介面。
function TClassFactory._AddRef: Integer;
begin
Inc(FLock);
end;
function TClassFactory._Release: Integer;
begin
Dec(FLock);
if FLock = 0 then
Free;
end;
function TClassFactory.QueryInterface(const IID: TGUID; out Obj): HResult;
begin
end;
其中，QueryInterface 我把它置空，因為在這個例子中，不需要向它查詢什麼介面。如果以後讀者需要向它查詢介面時，自己實現相關代碼。
同樣，在它的構造器中，也預先對計數加1
constructor TClassFactory.Create;
begin
Inc(FLock);
end;
到目前為止，我們已經基本實現了一個COM需要的大部分功能。現在，我們需要把它註冊到系統中，以便被其他程式調用。
l COM的註冊和反註冊
我們回過頭來，看看如何去實現那四個DLL的輸出函數。這四個函數的原形如下：
function DllGetClassObject(const CLSID, IID: TGUID; var Obj): HResult;stdcall;
function DllCanUnloadNow: HResult;stdcall;
function DllRegisterServer: HResult;stdcall;
function DllUnregisterServer: HResult;stdcall;
我們上面所說的類工廠的實例，就是在DllGetClassObject 中創建的。代碼如下：
function DllGetClassObject(const CLSID, IID: TGUID; var Obj): HResult;
begin
CF := TClassFactory.Create;
Pointer(obj) := Pointer(CF);
Result := S_OK;
end;
同樣的，我們只有一個類工廠，所以可以不理會前面那兩個參數。否則，就要根據不同GUID，來創建不同的類工廠物件。在這裏，我們直接把類工廠物件給返回了。
函數DllCanUnloadNow 用來註銷一個COM。在正常使用中，要根據引用計數，來判斷是否允許用戶註銷。在這裏我們直接返回S_OK，讓用戶直接註銷。
function DllCanUnloadNow: HResult;
begin
Result := S_OK;
end;
函數DllRegisterServer 用來向註冊表註冊一個COM元件資訊。要註冊一個COM，用戶必須知道COM在註冊表中的資訊是如何組織的。結構如下：
HKEY_CLASSES_ROOT
---- CLSID
---- GUID
----- InprocServer32 標明 COM所在磁片的路徑以及線程模型
----- ProgID 標明COM所實現的介面
----- TypeLib 標明 COM 的類型庫的GUID
----- Version 標明 COM的版本號。
當發生CreateCOMObject()調用時，輸入參數為COM的CLASS類型的GUID，系統將在註冊表中搜索到相關資訊，然後就可以找到該COM的位置，就可以開始調用了。
注意，如果您希望COM元件支援用戶端的CreateOLEObject()函數的調用，您必須還要註冊一個資訊：
HKEY_CLASSES_ROOT
----- 介面聲明
----- CLSID 標明 COM 介面和CLASS類型的GUID的對應關係。
那麼，當發生 CreateOLEObject 調用時，系統將會根據輸入參數（一個COM介面聲明，如a.b），去查找和介面對應的CLASS GUID，然後就可以讀到COM的相關資訊了。
全部代碼如下：
function DllRegisterServer: HResult;
var
lp: pchar;
ns: Dword;
begin
Result := S_FALSE;
Reg := TRegistry.Create;
GetMem(lp, 255);
try
Reg.RootKey := HKEY_CLASSES_ROOT;
if Reg.OpenKey('\MyCOM.MyCOMTest',true) then
begin
Reg.CreateKey('CLSID');
if Reg.OpenKey('CLSID',true) then
Reg.WriteString('',GUIDToString(Class_MyCOM));
end;
if Reg.OpenKey('\CLSID\' + GUIDToString(Class_MyCOM), true) then
begin
if Reg.CreateKey('InprocServer32') = false or
Reg.CreateKey('ProgID') = false or
Reg.CreateKey('TypeLib') = false or
Reg.CreateKey('Version') = false then
Exit;
Reg.WriteString('','MyCOM');
if Reg.OpenKey('\CLSID\' + GUIDToString(Class_MyCOM) +
'\InprocServer32', false) then
begin
Windows.GetModuleFileName(HInstance,lp, 255);
Reg.WriteString('', lp);
Reg.WriteString('ThreadingModel', 'Single');
end;
if Reg.OpenKey('\CLSID\' + GUIDToString(Class_MyCOM) + '\ProgID', false) then
Reg.WriteString('','MyCOM.MyCOMTest');
if Reg.OpenKey('\CLSID\' + GUIDToString(Class_MyCOM) + '\Version', false) then
Reg.WriteString('','1.0');
if Reg.OpenKey('\CLSID\' + GUIDToString(Class_MyCOM) + '\TypeLib', false) then
Reg.WriteString('',GUIDToString(LIBID_MyCOM));
Reg.CloseKey;
Result := S_OK;
end;
finally
begin
FreeMem(lp);
Reg.Free;
end;
end;
end;
函數DllUnregisterServer 則向系統登出一個COM的註冊資訊。它比較簡單，直接把COM的相關註冊鍵給刪除就是：
function DllUnRegisterServer: Hresult;
begin
Result := S_False;
Reg := TRegistry.Create;
try
Reg.RootKey := HKEY_CLASSES_ROOT;
Reg.DeleteKey('\CLSID\' + GUIDToString(Class_MyCOM));
Reg.CloseKey;
Finally
Reg.Free;
end;
end;
l 最後工作。
現在，我們編譯程序，然後生成一個DLL檔，在命令行下，使用：
regsvr32 MyCOM.dll
向系統註冊COM。
COM Client程式
在DELPHI中調用
新建一個專案，然後在單元中，定義介面資訊：
IMyCOMTest = interface(IUnknown)
['{D1C4A022-7F6F-42F0-A9B0-4A91703EB124}']
function msg: integer;stdcall;
end;
定義變數：
class_wjm: TGUID = '{CE38847E-A386-4753-89F1-34BE80042107}';
a: IMyCOMTest;
然後在視窗的OnCreate 事件裏，添加如下代碼：
procedure TForm1.FormCreate(Sender: TObject);
begin
//隨便用哪個都可以
a := createcomobject(class_wjm) as IMyCOMTest;
//或者使用 a := createoleobject('MyCOM.MyCOMTest') as IMyCOMTest;
end;
然後，放一個按鈕，並在其事件裏添加代碼：
procedure TForm1.Button1Click(Sender: TObject);
begin
showmessage(inttostr(a.msg));
end;
在窗口的OnCLose事件里加上：
procedure TForm1.FormClose(Sender: TObject; var Action: TCloseAction);
begin
a := nil;
end;
注意一定要釋放介面，否則可能是個難看的 AV 錯誤哦。
運行我們的程式，點下按鈕，你將看到輸出資訊“1978”。
如果你看不到正確的資訊，請仔細查看你的代碼是否和文中一致。你也可以直接向我索要源代碼。
在VC6中調用
稍微複雜點。先把GUID翻譯過來：
//{CE38847E-A386-4753-89F1-34BE80042107};
static const CLSID CLSID_MyCOM = {0xCE38847E,0xA386,0x4753,
{0x89,0xF1,0x34,0xBE,0x80,0x04,0x21,0x07}};
//{D1C4A022-7F6F-42F0-A9B0-4A91703EB124}
static const IID IID_MyCOM = {0xD1C4A022,0x7F6F,0x42F0,
{0xA9,0xB0,0x4A,0x91,0x70,0x3E,0xB1,0x24}};
然後在聲明一次介面的定義：
struct IMyCOMTest : public IUnknown
{
virtual LONG __stdcall msg();
};
IMyCOMTest* pLink;
然後放個按鈕上去，並在相關事件裏寫代碼：
void CMyvcView::OnButton6()
{
pLink = NULL;
int a =0;
CoInitialize(NULL);
a = CoCreateInstance(CLSID_MyCOM, NULL,
CLSCTX_INPROC_SERVER,IID_MyCOM, (void**)&pLink);
if (a==S_OK){
LONG a= pLink->msg();
};
}
注意，一定要記住調用 CoInitialize(NULL); 這個函數，否則COM無法使用的。
編譯運行，你應該能看到 a 是等於1978 的。
總結
到目前為止，我們成功的編寫了一個最簡單的COM元件，並且在DELPHI和VC中成功調用。這都說明我們的工作是成功的。同時我們也看到，實現一個COM，並不難。
關於進程外的COM以及DCOM，前者是基於LPC 本地程序呼叫，後者是基於RPC遠端程序呼叫。除了協議不同外，其他的都一樣。大家有興趣，可以以後繼續討論。
關於COM的線程模式，我曾經以為，是COM嚮導中自動會產生對應的線程代碼，來實現多線程的。但是我後來又認為，根本沒有這回事，COM只是做了個標記，告訴作業系統他的線程模型，至於如何產生線程，則是作業系統做的。有關這方面的討論，還需要進一步研究。
一個小尾巴
我們知道，在DELPHI裏，有一個Import Type Library 的功能。可以把一個COM元件導到DELPHI中直接使用。但是，如果我們試圖把我們剛才寫的那個元件，也ADD進去的時候，DELPHI會提示：
載入類型庫/DLL時出錯。
這是怎麼回事呢？ 原來，這是MS/BORLAND的一個小花招。我們看看VCL的代碼就知道了，在DELPHI的嚮導為你創建一個COM時，它偷偷地加了一個IprovideClassInfo 的介面進去，該介面使用ItypeInfo 介面，主要用於向外提供COM的類型資訊的。大家仔細跟下TtypedComObject 這個類，就會發現這個奧秘了。在前例中，我們沒有實現這個介面，那麼當然無法被DELPHI載入了。關於如何實現這個介面，已經超出了本文的範圍，所以不於討論。
有興趣的朋友，可以繼續關注 “COM實現過程（2）”，主要講述如何實現類型庫的。
2002/6/27
版權所有
轉載時請包括作者姓名
實用相關搜尋: ua now 翻譯 av 討論 狗 花 it cef ati
設為首頁
加入收藏
