|
|
|
|
Win32彙編教程八
您是第
392個瀏覽者
有關GDI和點陣圖
GDI 即圖形設備介面，是 Windows 最重要的部分之一，它大部分由 GDI32.DLL 庫中的 API 來處理，GDI 的主要目的之一是支援與設備無關的圖形編程，對於 Dos 下的圖形編程，很多人可能“心有餘悸”，因為PC 中有太多種類的顯示卡，而幾乎每個顯示卡的處理都是不同的，即使後來有了 Vesa 編程，我們還是不能全部撇開具體的硬體，Windows GDI 使我們對圖形的編程變得相對簡單了很多，由於GDI 是 Windows 最龐大的部分，並不是幾句話能講清楚的，本節要講的是 Windows 下GDI 的基本處理步驟和簡單的點陣圖處理，並沒有涉及到 Directx 一類的編程。只希望能對朋友們有所啟發。
Windows 並不允許程式師訪問顯示硬體，它的所有對螢幕的操作是通過環境設備（DC）來處理的，螢幕上的每一個視窗對應一個DC，你可以把一個DC 想像成這個視窗的視頻緩衝區，你對DC的操作結果會反映到螢幕上，在視窗的DC之外，你也可以自己建立DC，這相當於建立一個記憶體中的緩衝區，你對這個DC的操作結果保存在記憶體中。你也可以用 API 在不同的DC之間拷貝資料，比如說你可以在記憶體DC 中先建立好資料，然後拷貝到視窗的DC中，就相當於完成了螢幕的刷新。
與DC的取得、建立取消有關的API有以下幾種： GetDC(hWnd) - 取得某個窗口的DC，API 返回對應的 DC 控制碼
ReleaseDC(hWnd,hDC) - 釋放用 GetDC 取得的 DC 控制碼
CreateCompatibleDC(hDC) - 從一個已知的 DC 控制碼中建立一個記憶體 DC，各種參數、屬性參考已知的 DC
DeleteDC(hDC) - 刪除用CreateCompatibleDC 建立的 DC
上面的4個API，必須成對出現，用 GetDC 取得的DC 必須用 ReleaseDC 釋放，而用 CreateCompatibleDC 建立的 DC 必須用 DeleteDC 刪除，不能混淆。DC 的作用範圍：用 GetDC 取得的視窗 DC 必須儘快釋放，你不應該在 Windows 的不同消息之間保存 DC 控制碼，而用 CreateCompatibleDC 建立的 DC 可以長期保存，舉例說明，如果你在 WM_PAINT 和 WM_SIZE 消息中都要對視窗的 DC 進行操作，你不能在 WM_INIT 時先 GetDC，然後保存控制碼，最後在 WM_CLOSE 消息時 ReleaseDC，而是必須在 WM_PAINT 和 WM_SIZE 開始的地方 GetDC，在消息結束的地方就 ReleaseDC，而用 CreateCompatibleDC 建立的則相反，你可以在 WM_INIT 時建立，在 WM_CLOSE 時刪除。
如果想把一個位圖畫到 DC 中，你只需簡單的用 invoke SelectObject,hDc,hBitmap 就行了，是不是很簡單？但圖形操作並不是單單把點陣圖放入螢幕就行了，還要涉及到位的操作，如把前景點陣圖的邊緣去掉貼入背景點陣圖等。 Windows 的 GDI 提供了下面一些 DC 間的拷貝 API，中間就包括了拷貝的模式：
BitBlt hDcDest,XDest,YDest,Width,Height,hDcSource,XSrc,YSrc,dwRop
這個 API 把 hDcSource 的 XSrc,YSrc 座標處的內容拷貝到 hDcDest 的 XDest,YDest 處，拷貝大小為 Width,Height。
PatBlt hDc,X,Y,Width,Height,dwRop 是用預定義的刷子等 Object 填充 DC
StretchBlt,hDcDest,XDest,YDest,Width,Height,hDcSource,XSrc,YSrc,WidthSrc,HeightSrc,dwRop 是拷貝並自動縮放大小，你可以注意到它和 BitBlt 相比多了兩個參數 WidthSrc 和 HeightSrc，別的都是一樣的。
以上API 中的 dwRop 參數是最關鍵的，它的值有 SRCCOPY，SRCPAINT，SRCAND，DSTINVERT 等，表示源DC 拷貝到目標DC後象素的計算方法，SRCCOPY 表示用源DC覆蓋目標DC，SRCPAINT是執行 OR 操作，SRCAND 是執行 AND 操作，DSTINVERT 是取反，舉例說明，如果源DC中的某一點是黑色，目標DC對應的點是紅色，那麼用 SRCCOPY後，目標DC的點變成黑色，用SRCPAINT 後還是紅色，因為黑 (000000) or 紅(0000ff) ＝紅(0000ff)。
對應一般對螢幕或視窗進行圖形操作的步驟如下。
用GetDC 取得目標視窗的 DC
用 CreateCompatibleDC 建立一個記憶體中的 DC用作緩衝區
用 SelectObject 填充記憶體DC 或別的辦法對記憶體DC進行操作，一句話，先把要顯示的東西處理好
用 BitBlt 把記憶體DC 拷貝到視窗 DC中，完成螢幕刷新。
本節的例副程式是一個螢幕放大鏡，它把滑鼠移動到的地方的螢幕內容放大一倍顯示到自己的視窗中。
根源程式 - 彙編原始檔案
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; Programmed by 羅雲彬, bigluo@telekbird.com.cn
; Website: http://asm.yeah.net
; LuoYunBin's Win32 ASM page (羅雲彬的編程樂園)
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; 版本資訊
; 彙編教程附帶根源程式 - 螢幕放大器
; V1.0 ------ 2000年7月1日
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
.386
.model flat, stdcall
option casemap :none ; case sensitive
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; Include 數據
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
include windows.inc
include user32.inc
include kernel32.inc
include comctl32.inc
include comdlg32.inc
include gdi32.inc
includelib user32.lib
includelib kernel32.lib
includelib comctl32.lib
includelib comdlg32.lib
includelib gdi32.lib
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; Equ 數據
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
DLG_MAIN equ 1000
ID_BITMAP equ 1001
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; 資料段
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
.data?
hWinPic dd ?
hDcMem dd ?
hBitmap dd ?
hWinDesktop dd ?
hInstance dd ?
szBuffer db 256 dup (?)
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; 副程式聲明
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
_ProcDlgMain PROTO  WORD,WORD,WORD,:DWORD
.data
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; 代碼段
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
.code
include Win.asm
;********************************************************************
_ProcDlgMain proc uses ebx edi esi, \
hWnd:DWORD,wMsg:DWORD,wParam:DWORD,lParam:DWORD
local @stPoint OINT
local @hDcDesktop,@hDcPic
mov eax,wMsg
.if eax == WM_CLOSE
invoke EndDialog,hWnd,NULL
invoke KillTimer,hWnd,1
invoke DeleteDC,hDcMem
invoke DeleteObject,hBitmap
; *******************************************************************
.elseif eax == WM_INITDIALOG
invoke GetDlgItem,hWnd,ID_BITMAP
mov hWinPic,eax
invoke GetDeskto宣傳0250ow
mov hWinDesktop,eax
invoke SetWindowPos,hWnd,HWND_TOPMOST,0,0,0,0,\
SWP_NOMOVE or SWP_NOSIZE
; *******************************************************************
invoke GetDC,hWinDesktop
mov @hDcDesktop,eax
invoke CreateCompatibleDC,@hDcDesktop
mov hDcMem,eax
invoke CreateCompatibleBitmap,@hDcDesktop,80,80
mov hBitmap,eax
invoke SelectObject,hDcMem,hBitmap
invoke ReleaseDC,hWinDesktop,@hDcDesktop
invoke SetTimer,hWnd,1,100,NULL
; *******************************************************************
.elseif eax == WM_TIMER
invoke GetCursorPos,addr @stPoint
sub @stPoint.x,20
sub @stPoint.y,20
.if @stPoint.x < 0
mov @stPoint.x,0
.endif
.if @stPoint.y < 0
mov @stPoint.y,0
.endif
invoke GetDC,hWinDesktop
mov @hDcDesktop,eax
invoke GetDC,hWinPic
mov @hDcPic,eax
invoke PatBlt,hDcMem,0,0,80,80,BLACKNESS
invoke StretchBlt,hDcMem,0,0,80,80,\
@hDcDesktop,@stPoint.x,@stPoint.y,40,40,SRCCOPY
invoke BitBlt,@hDcPic,0,0,80,80,\
hDcMem,0,0,SRCCOPY
invoke ReleaseDC,hWinDesktop,@hDcDesktop
invoke ReleaseDC,hWinPic,@hDcPic
.else
;********************************************************************
; 注意：對話方塊的消息處理後，要返回 TRUE,對沒有處理的消息
; 要返回 FALSE
;********************************************************************
mov eax,FALSE
ret
.endif
mov eax,TRUE
ret
_ProcDlgMain endp
;********************************************************************
start:
invoke GetModuleHandle,NULL
mov hInstance,eax
invoke DialogBoxParam,hInstance,DLG_MAIN,NULL,offset _ProcDlgMain,0
invoke ExitProcess,NULL
end start
程式的分析和要點
在程式的初始化中，我們用GetDc 取的桌面的螢幕的 DC，再用 CreateCompatibleDC 建立一個記憶體DC做緩衝區，建立一個點陣圖再用 SelectObject 把 hDcMem 設置為這個點陣圖是為了是 hDcMem 的大小變為 80x80。
invoke GetDC,hWinDesktop
mov @hDcDesktop,eax
invoke CreateCompatibleDC,@hDcDesktop
mov hDcMem,eax
invoke CreateCompatibleBitmap,@hDcDesktop,80,80
mov hBitmap,eax
invoke SelectObject,hDcMem,hBitmap
invoke ReleaseDC,hWinDesktop,@hDcDesktop
然後在程式的每 0.1 秒一次的 WM_TIMER 計時器消息中，我們先用 GetDC 取得桌面和對話方塊中文本框的控制碼，然後用 PatBlt 把記憶體DC清除為黑色，再用 StretchBlt 從桌面DC中拷貝 40x40的區域到記憶體 DC 中，新的大小是 80x80（放大功能就是這樣實現的），拷貝的位置是用 GetCursorPos 取得的，也就是滑鼠的當前位置，最後用 BitBlt 把記憶體DC 拷貝到對話方塊中。如果直接把桌面DC 拷貝到對話方塊中也可以，但是當滑鼠移動到螢幕邊緣上時，由於螢幕外的點是無效的，所以對話方塊中的一部分會花屏，大家可以改動程式試試。
invoke GetCursorPos,addr @stPoint
invoke GetDC,hWinDesktop
mov @hDcDesktop,eax
invoke GetDC,hWinPic
mov @hDcPic,eax
invoke PatBlt,hDcMem,0,0,80,80,BLACKNESS
invoke StretchBlt,hDcMem,0,0,80,80,\
@hDcDesktop,@stPoint.x,@stPoint.y,40,40,SRCCOPY
invoke BitBlt,@hDcPic,0,0,80,80,\
hDcMem,0,0,SRCCOPY
invoke ReleaseDC,hWinDesktop,@hDcDesktop
invoke ReleaseDC,hWinPic,@hDcPic
實用相關搜尋: map nds bus lg 花 it ati model sm dc
|
〓中國黑客聯盟（CHU）〓前核心成員，現為榮譽會員
〓中國黑客聯盟（CHU）〓網絡電子雜誌《矩陣》編輯
風堂技術工作室
|
|
|
|
設為首頁
加入收藏
