|
|
|
|
Win32彙編教程七
您是第
265個瀏覽者
有關控制項子類化
說到類，大家可能馬上就想到C++，的確，類首先是在C中提出的，但是，這個概念在 Win32Asm 中仍然適用，因為在類的思路是這樣的：先假設某個物件有不同的屬性，當一個新的物件的某個屬性和上面所說的物件有些不同，而別的屬性一模一樣，那麼實際上除了處理這個屬性的代碼有些不同外，別的代碼完全可以使用前面的物件的代碼。在具體的應用中，我舉個例子，比如說我們定義一個 "edit" 控制項，那麼這個控制項的行為是由 Windows 內定的，因為它的視窗過程是在 Windows 系統內部的，但假如我們想編一個有語法檢查的 "edit" 控制項，是否我們除了語法檢查的代碼以外，還要編寫很多代碼來實現老的 "edit" 控制項一模一樣的功能呢？答案當然是否定的，實際上，我們可以截獲一個標準 "edit"控制項的 WM_CHAR 消息，檢查鍵入的鍵並做處理，別的消息可以傳給原來的視窗過程。示意如下： 在子類化之前： Windows => edit 控制項的視窗過程
在子類化之後： Windows => 我們的過程代碼 => edit 控制項的視窗過程
在Windows 的 API 中有個函數可以用來實現這個功能，那就是 SetWindowLong PROTO hWnd,nIndex,dwNewLong ，參數的意思是 hWnd 是你要改變的視窗控制碼，nIndex 是我們要改變視窗的什麼屬性，它的值可以是 GWL_EXSTYLE：改變視窗風格，GWL_WNDPROC：設置視窗的新的過程，這正是我們感興趣的，還有是 GWL_USERDATA 這是視窗自定義的一個32位元的資料。dwNewLong 是新的值，還有一個 API 是用來調用原來的視窗過程的，叫 CallWindwoProc PROTO lpPrevWndFunc,hWnd,Msg,wParam,lParam。
我們在使用時有下面的過程：
用 SetWindowLong,hWnd,GWL_WNDPROC,addr _NewProcAddress 設置我們自己的代碼的地址，API 返回原來的過程地址
用 SetWindowLong,hWnd,GWL_USERDATA,eax 把原來的過程位址保存在自定義資料中。
這樣，所有消息會先送到我們的過程中，然後在我們自己的過程中：
對要處理的消息進行處理，如果不希望原來的過程再處理，那麼返回。
對自己不處理的消息，調用原來的視窗過程處理，並把返回值返回。方法是：
用 invoke GetWindowLong,hWnd,GWL_USERDATA 取出自定義資料中保存的原過程位址
用 invoke CallWindowProc,eax,hWnd,uMsg,wParam,lParam 調用原過程 UINT uStructSize}
本節教程提供了一個根源程式，它是實現對話方塊中的文本的 URL 連接過程，我們看到有的程式中的文本是藍色的，有下劃線，然後滑鼠移動到上面會變手型，就象流覽器中的超聯結一樣，而且按下會自動連接到網站上，仔細想想，我們並沒有一個標準的控制項或 API 來實現這樣一個功能，因為這首先是一個文本，所以我們可以對這個文本進行子類化，處理它的WM_LBUTTONUP 消息來實現按下自動連上網站的功能；處理 WM_SETCURSOR 消息來讓滑鼠移到上面改變游標，具體根源程式如下：
根源程式 - 資源檔案
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
;************************************************
#include
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; Icon 1000 開始
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
#define IDI_MAIN 1000
#define IDC_HANDLE 2000
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; 對話方塊 3000 開始
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
#define DLG_ABOUT 3000
#define ID_EMAIL 3001
#define ID_HOMEPAGE 3002
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; 資源定義開始
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
IDI_MAIN ICON "Main.ico"
IDC_HANDLE CURSOR "Handle.cur"
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
DLG_ABOUT DIALOG DISCARDABLE 50, 50, 160, 30
STYLE DS_MODALFRAME | WS_POPUP | WS_CAPTION | WS_SYSMENU
CAPTION "URL 聯結文本演示 - by 羅雲彬"
FONT 9, "宋體"
BEGIN
LTEXT "我的主頁: ",-1, 5,5,54,9
LTEXT "http://asm.yeah.net", ID_HOMEPAGE, 55,5,80,9
LTEXT "我的E-mail: ", -1, 5,17,54,9
LTEXT "[email=bigluo@telekbird.com.cn%22,ID_EMAIL]bigluo@telekbird.com.cn",ID_EMAIL[/email], 55,17,95,9
END
根源程式 - 彙編原始檔案
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; 是否包括調試代碼
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
DEBUG = 0
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; Programmed by 羅雲彬, bigluo@telekbird.com.cn
; Website: http://asm.yeah.net
; LuoYunBin's Win32 ASM page (羅雲彬的編程樂園)
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; 版本資訊
; 視窗子類化演示程式 Ver 1.0
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
.386
.model flat, stdcall
option casemap :none ; case sensitive
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; Include 數據
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
include windows.inc
include user32.inc
include kernel32.inc
include comctl32.inc
include comdlg32.inc
include shell32.inc
include gdi32.inc
includelib user32.lib
includelib kernel32.lib
includelib comctl32.lib
includelib comdlg32.lib
includelib shell32.lib
includelib gdi32.lib
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; Equ 數據
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
IDI_MAIN equ 1000 ;icon
IDC_HANDLE equ 2000 ;handle cursor
DLG_ABOUT equ 3000 ;dialog - about
ID_EMAIL equ 3001
ID_HOMEPAGE equ 3002
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; 資料段
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
.data?
hInstance dd ?
hIcon dd ?
szBuffer db 256 dup (?)
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
_HyperLinkProc proto  WORD,WORD,WORD,:DWORD
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
.data
hCursorHandle dd ?
szHomePage db "http://asm.yeah.net",0
szEmail db "mailto:bigluo@telekbird.com.cn"
db "?subject=嗨！我喜歡你的程式！",0
.code
if DEBUG
include Debug.asm
endif
;********************************************************************
; 關於對話方塊中超級連接的視窗程式
;********************************************************************
_HyperLinkProc proc hWnd:DWORD,uMsg:DWORD,wParam:DWORD,lParam:DWORD
mov eax,uMsg
.if eax == WM_LBUTTONUP
invoke GetDlgCtrlID,hWnd
.if eax == ID_HOMEPAGE
invoke ShellExecute,0,0,offset szHomePage,0,0,0
.elseif eax == ID_EMAIL
invoke ShellExecute,0,0,offset szEmail,0,0,0
.endif
.elseif eax == WM_NCHITTEST
;將 WM_NCHITTEST 返回 TRUE 可以接收滑鼠動作，實現按下功能 !
mov eax,TRUE
ret
.elseif eax == WM_SETCURSOR
invoke SetCursor,hCursorHandle
.else
invoke GetWindowLong,hWnd,GWL_USERDATA
invoke CallWindowProc,eax,hWnd,uMsg,wParam,lParam
ret
.endif
xor eax,eax
ret
_HyperLinkProc endp
;********************************************************************
; 對話方塊窗口主程序
;********************************************************************
AboutDialogProc proc uses ebx edi esi, \
hWnd:DWORD,uMsg:DWORD,wParam:DWORD,lParam:DWORD
local @stWindow:RECT
local @dwWidth:DWORD,@dwHeight:DWORD
local @hWinTemp:DWORD
local @stFont OGFONT,@hFontOutput:DWORD
mov eax,uMsg
.if eax == WM_CLOSE
invoke EndDialog,hWnd,NULL
.elseif eax == WM_INITDIALOG
invoke GetModuleHandle,NULL
invoke LoadCursor,eax,IDC_HANDLE
mov hCursorHandle,eax
invoke GetDlgItem,hWnd,ID_HOMEPAGE
mov @hWinTemp,eax
invoke SetWindowLong,@hWinTemp,GWL_WNDPROC,addr _HyperLinkProc
invoke SetWindowLong,@hWinTemp,GWL_USERDATA,eax
invoke GetDlgItem,hWnd,ID_EMAIL
mov @hWinTemp,eax
invoke SetWindowLong,@hWinTemp,GWL_WNDPROC,addr _HyperLinkProc
invoke SetWindowLong,@hWinTemp,GWL_USERDATA,eax
.elseif eax == WM_CTLCOLORSTATIC
invoke GetDlgCtrlID,lParam
.if eax == ID_HOMEPAGE || eax == ID_EMAIL
invoke SendMessage,lParam,WM_GETFONT,0,0
mov @hFontOutput,eax
invoke GetObject,@hFontOutput,sizeof LOGFONT,addr @stFont
mov @stFont.lfUnderline,TRUE
invoke CreateFontIndirect,addr @stFont
mov @hFontOutput,eax
invoke SelectObject,wParam,eax
invoke SetTextColor,wParam,Blue
invoke GetSysColor,COLOR_MENU
invoke SetBkColor,wParam,eax
invoke DeleteObject,@hFontOutput
;********************************************************************
; 注意此處一定要把StockOject的返回值返回，否則無法顯示顏色
;********************************************************************
invoke GetStockObject,HOLLOW_BRUSH
.else
mov eax,FALSE
ret
.endif
ret
.else
;********************************************************************
; 注意：對話方塊的消息處理後，要返回 TRUE,對沒有處理的消息
; 要返回 FALSE
;********************************************************************
mov eax,FALSE
ret
.endif
mov eax,TRUE
ret
AboutDialogProc endp
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; 程式開始
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
start:
invoke InitCommonControls
invoke GetModuleHandle,NULL
mov hInstance,eax
invoke DialogBoxParam,hInstance,DLG_ABOUT,\
NULL,offset AboutDialogProc,DLG_ABOUT
invoke ExitProcess,NULL
;********************************************************************
end start
程式的分析和要點
在資源中，我們定義了兩個文本框，ID 分別為 ID_HOMEPAGE 和 ID_EMAIL，在主對話方塊的過程的 initdialog 消息中，我們用 GetDlgItem 取的它們的 hWnd，然後進行子類化，我們把新的過程設置到了 _HyperLinkProc 中
invoke GetDlgItem,hWnd,ID_HOMEPAGE
mov @hWinTemp,eax
invoke SetWindowLong,@hWinTemp,GWL_WNDPROC,addr _HyperLinkProc
invoke SetWindowLong,@hWinTemp,GWL_USERDATA,eax
invoke GetDlgItem,hWnd,ID_EMAIL
mov @hWinTemp,eax
invoke SetWindowLong,@hWinTemp,GWL_WNDPROC,addr _HyperLinkProc
invoke SetWindowLong,@hWinTemp,GWL_USERDATA,eax
然後在新的處理過程中，檢測到 WM_LBUTTONUP 消息（滑鼠左鍵放開）就使用 ShellExecute API 來連到網站，檢測 WM_NCHITTEST 來使文本控制項接收滑鼠的消息，檢測 WM_SETCURSOR 消息把游標設置成手形，對這些消息以外的消息我們是不處理的，那就用 CallWindowProc 來調用原來的過程進行處理。
.if eax == WM_LBUTTONUP
invoke GetDlgCtrlID,hWnd
.if eax == ID_HOMEPAGE
invoke ShellExecute,0,0,offset szHomePage,0,0,0
.elseif eax == ID_EMAIL
invoke ShellExecute,0,0,offset szEmail,0,0,0
.endif
.elseif eax == WM_NCHITTEST
;將 WM_NCHITTEST 返回 TRUE 可以接收滑鼠動作，實現按下功能 !
mov eax,TRUE
ret
.elseif eax == WM_SETCURSOR
invoke SetCursor,hCursorHandle
.else
invoke GetWindowLong,hWnd,GWL_USERDATA
invoke CallWindowProc,eax,hWnd,uMsg,wParam,lParam
ret
.endif
實用相關搜尋: map nds bus lg she it model sm shell dc
|
〓中國黑客聯盟（CHU）〓前核心成員，現為榮譽會員
〓中國黑客聯盟（CHU）〓網絡電子雜誌《矩陣》編輯
風堂技術工作室
|
|
|
|
設為首頁
加入收藏
