|
|
|
|
Win32彙編教程六
您是第
272個瀏覽者
有關工具欄和狀態欄
工具欄和狀態欄也是Windows標準介面的組成部分，工具欄一般位於功能表欄的下方，上面是一些系統定義的或自己定義的圖片，可以通俗地顯示這個按鈕的作用。狀態欄一般位於視窗的最下方，用來顯示程式運行中的一些資訊。工具欄和狀態欄是Windows系統的兩個通用的控制項，你可以通過兩個專用的 API 或者利用 CreateWindowEx 再使用制定的已經由系統定義的類來創建它們。這兩個 API 分別是 CreateToolbarEx 和 CreateStatusWindow。下面將一下它們的用法。
CreateToolbarEx 的聲明為： HWND CreateToolbarEx(
HWND hwnd,
DWORD ws,
UINT wID,
int nBitmaps,
HINSTANCE hBMInst,
UINT wBMID,
LPCTBBUTTON lpButtons,
int iNumButtons,
int dxButton,
int dyButton,
int dxBitmap,
int dyBitmap,
UINT uStructSize}
它的參數中 hwnd 是父視窗（也就是我們的主視窗）的控制碼，ws 是工具欄的風格，可以由幾項合成，如 WS_VISIBLE 是創建是可見，TBSTYLE_FLAT表示平面按鈕，WS_BORDER表示有邊線等，具體可以見手冊。wID 是工具欄的標識，nBitmaps 是定義按鈕的圖片個數，因為如果你要使用自己的圖片，所有圖片是要放在同一行中的，然後就由你自己指定中間的個數， hBMInst 是包含已定義系統圖片的資源控制碼，在你不想自己畫圖，使用內定的標準圖片時使用，一般包含這些圖片的 hInstance 已經在 Widnows.inc 中定義為 HINST_COMMCTRL，同樣 wBMID 一般是 IDB_STD_SMALL_COLOR，表示使用大圖片還是小圖片等等。接下來是定義按鈕的資料結構，中間定義了各個按鈕的命令號，圖片號及其他屬性，結構如下：
TBBUTTON STRUCT
iBitmap DWORD ?
idCommand DWORD ?
fsState BYTE ?
fsStyle BYTE ?
bReserved BYTE 2 dup(?)
dwData DWORD ?
iString DWORD ?
TBBUTTON ENDS
其中，每個結構定義一個按鈕，資料結構中iBitmap 是圖片ID，idCommand 是按鈕的命令號，這個命令號當你按下按鈕的時候會出現在 WM_COMMAND 消息的 wParam 中，你就可以知道哪個按鈕被按下了。fsState 是按鈕的初始狀態，如 TBSTATE_PRESSED 是已經按下的，詳細見手冊，fsStyle 是風格。
而建立狀態欄的 CreateStatusWindow 的聲明如下：
HWND CreateStatusWindow(
LONG style,
LPCTSTR lpszText,
HWND hwndParent,
UINT wID
);
style 是狀態欄的風格，lpszText 指向初始化是要顯示在狀態欄的文本，你可以指向 NULL。hwndParent 是父窗口的控制碼。wID 是窗口 ID。
使用工具欄和狀態欄的根源程式
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; 是否包括調試代碼
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
DEBUG = 1
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; Programmed by 羅雲彬, bigluo@telekbird.com.cn
; Website: http://asm.yeah.net
; LuoYunBin's Win32 ASM page (羅雲彬的編程樂園)
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; 版本資訊
; 工具欄和狀態欄演示程式 Ver 1.0
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
.386
.model flat, stdcall
option casemap :none ; case sensitive
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; Include 數據
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
include windows.inc
include user32.inc
include kernel32.inc
include comctl32.inc
include comdlg32.inc
include gdi32.inc
includelib user32.lib
includelib kernel32.lib
includelib comctl32.lib
includelib comdlg32.lib
includelib gdi32.lib
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; Equ 數據
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
IDI_MAIN equ 1000 ;icon
IDM_MAIN equ 4000 ;menu
IDM_TOOLBAR equ 4001
IDM_STATUSBAR equ 4002
IDM_EXIT equ 4003
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; 資料段
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
.data?
hInstance dd ?
hWinMain dd ?
hMenu dd ?
hIcon dd ?
hToolbar dd ?
hStatusbar dd ?
szBuffer db 256 dup (?)
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; 資料段
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
.data
szClassName db "Toolbar Template",0
szCaptionMain db '工具欄和狀態欄演示程式 - 羅雲彬',0
dwFlag dd F_TOOLBAR or F_STATUSBAR
;********************************************************************
; 標誌位元定義
F_TOOLBAR equ 00000001b
F_STATUSBAR equ 00000010b
stToolbar TBBUTTON < STD_FILENEW,1,TBSTATE_ENABLED,TBSTYLE_BUTTON,2 dup(0),-1>
TBBUTTON <0,0,TBSTATE_ENABLED,TBSTYLE_SEP,2 dup(0),-1>
TBBUTTON < STD_FILEOPEN,2,TBSTATE_ENABLED,TBSTYLE_BUTTON,2 dup(0),-1>
TBBUTTON < STD_FILESAVE,3,TBSTATE_ENABLED,TBSTYLE_BUTTON,2 dup(0),-1>
TBBUTTON <0,0,TBSTATE_ENABLED,TBSTYLE_SEP,2 dup(0),-1>
TBBUTTON < STD_PRINT,4,TBSTATE_ENABLED,TBSTYLE_BUTTON,2 dup(0),-1>
TBBUTTON < STD_PRINTPRE,0,TBSTATE_ENABLED,TBSTYLE_SEP,2 dup(0),-1>
NUM_BUTTONS EQU 7
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; 代碼段
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
.code
if DEBUG
include Debug.asm
endif
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; 程式開始
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
start:
call _WinMain
invoke ExitProcess,NULL
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; 主視窗程式
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
_WinMain proc
local @stWcMain:WNDCLASSEX
local @stMsg:MSG
;********************************************************************
; 如果已經在運行，則啟動已運行的進程
;********************************************************************
invoke FindWindow,offset szClassName,NULL
.if eax != NULL
invoke ShowWindow,eax,SW_SHOWNORMAL
invoke ExitProcess,NULL
.endif
invoke InitCommonControls
invoke GetModuleHandle,NULL
mov hInstance,eax
invoke LoadIcon,hInstance,IDI_MAIN
mov hIcon,eax
invoke LoadMenu,hInstance,IDM_MAIN
mov hMenu,eax
;*************** 註冊視窗類 *****************************************
invoke LoadCursor,0,IDC_ARROW
mov @stWcMain.hCursor,eax
mov @stWcMain.cbSize,sizeof WNDCLASSEX
mov @stWcMain.hIconSm,0
mov @stWcMain.style,CS_HREDRAW or CS_VREDRAW
mov @stWcMain.lpfnWndProc,offset WndMainProc
mov @stWcMain.cbClsExtra,0
mov @stWcMain.cbWndExtra,0
mov eax,hInstance
mov @stWcMain.hInstance,eax
mov @stWcMain.hIcon,0
mov @stWcMain.hbrBackground,COLOR_BTNFACE+1
mov @stWcMain.lpszClassName,offset szClassName
mov @stWcMain.lpszMenuName,0
invoke RegisterClassEx,addr @stWcMain
;*************** 建立輸出視窗 ***************************************
invoke CreateWindowEx,NULL,\ ;WS_EX_CLIENTEDGE,\
offset szClassName,offset szCaptionMain,\
WS_OVERLAPPEDWINDOW,\ ; OR WS_VSCROLL OR WS_HSCROLL,\
50,50,550,350,\
NULL,hMenu,hInstance,NULL
invoke ShowWindow,hWinMain,SW_SHOWNORMAL
invoke UpdateWindow,hWinMain
;*************** 消息迴圈 *******************************************
.while TRUE
invoke GetMessage,addr @stMsg,NULL,0,0
.break .if eax == 0
invoke TranslateMessage,addr @stMsg
invoke DispatchMessage,addr @stMsg
.endw
ret
_WinMain endp
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
WndMainProc proc uses ebx edi esi, \
hWnd WORD,uMsgWORD,wParamWORD,lParam:DWORD
mov eax,uMsg
.if eax == WM_CREATE
mov eax,hWnd
mov hWinMain,eax
call _Init
;********************************************************************
.elseif eax == WM_SIZE
invoke SendMessage,hStatusbar,uMsg,wParam,lParam
invoke SendMessage,hToolbar,uMsg,wParam,lParam
;********************************************************************
.elseif eax == WM_COMMAND
mov eax,wParam
movzx eax,ax
.if eax == IDM_EXIT
call _Quit
.elseif eax == IDM_TOOLBAR
xor dwFlag,F_TOOLBAR
call _ArrangeWindow
.elseif eax == IDM_STATUSBAR
xor dwFlag,F_STATUSBAR
call _ArrangeWindow
.else
_Debug "功能表和工具欄命令\","命令ID",eax
.endif
;********************************************************************
.elseif eax == WM_CLOSE
call _Quit
;********************************************************************
.else
invoke DefWindowProc,hWnd,uMsg,wParam,lParam
ret
.endif
;********************************************************************
; 注意：WndProc 處理 Windows 消息後，必須在 Eax 中返回 0
; 但是由 DefWindowProc 處理後的返回值不能改變，否則視窗
; 將無法顯示!
;********************************************************************
xor eax,eax
ret
WndMainProc endp
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; 主視窗控制副程式
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
_Init proc
invoke SendMessage,hWinMain,WM_SETICON,ICON_SMALL,hIcon
invoke CreateToolbarEx,hWinMain,\
WS_VISIBLE or WS_CHILD or TBSTYLE_FLAT or WS_BORDER,\
1,0,HINST_COMMCTRL,IDB_STD_SMALL_COLOR,offset stToolbar,\
NUM_BUTTONS,0,0,0,0,sizeof TBBUTTON
mov hToolbar,eax
invoke CreateStatusWindow,WS_CHILD or WS_VISIBLE,NULL,hWinMain,2
mov hStatusbar,eax
call _ArrangeWindow
ret
_Init endp
;********************************************************************
_Quit proc
invoke DestroyWindow,hWinMain
invoke PostQuitMessage,NULL
ret
_Quit endp
;********************************************************************
_ArrangeWindow proc
local @stRect:RECT
local @stRectTemp:RECT
local @dwWidth:DWORD
test dwFlag,F_TOOLBAR
.if ZERO?
invoke ShowWindow,hToolbar,SW_HIDE
invoke CheckMenuItem,hMenu,IDM_TOOLBAR,MF_UNCHECKED
.else
invoke ShowWindow,hToolbar,SW_SHOW
invoke CheckMenuItem,hMenu,IDM_TOOLBAR,MF_CHECKED
.endif
test dwFlag,F_STATUSBAR
.if ZERO?
invoke ShowWindow,hStatusbar,SW_HIDE
invoke CheckMenuItem,hMenu,IDM_STATUSBAR,MF_UNCHECKED
.else
invoke ShowWindow,hStatusbar,SW_SHOW
invoke CheckMenuItem,hMenu,IDM_STATUSBAR,MF_CHECKED
.endif
ret
_ArrangeWindow endp
;********************************************************************
end start
程式的分析和要點
在工具欄和狀態欄編程中，要注意的就是工具欄和狀態欄並不會隨父視窗的大小變化自己調整位置和大小，所以要在父視窗的 WM_SIZE 消息中來移動和調整它們，這可以簡單的把 WM_SIZE 消息傳給它們就行了。不必自己再去計算。
.elseif eax == WM_SIZE
invoke SendMessage,hStatusbar,uMsg,wParam,lParam
invoke SendMessage,hToolbar,uMsg,wParam,lParam
另外，工具欄和狀態欄也是一種子視窗，所以如果想把它們隱藏或顯示的話，可以用標準的 ShowWindow 來處理。
實用相關搜尋: map nds bus now lg it pda model sm dc
|
〓中國黑客聯盟（CHU）〓前核心成員，現為榮譽會員
〓中國黑客聯盟（CHU）〓網絡電子雜誌《矩陣》編輯
風堂技術工作室
|
|
|
|
設為首頁
加入收藏
