|
|
|
|
Win32彙編教程五
您是第
282個瀏覽者
有關功能表和加速鍵
功能表是Windows標準介面的最重要的組成部分，視窗的功能表條位於標題欄的下方，這個功\能表通常被稱為主功能表，列在主功\能表下面的功能表項被稱為下拉式菜單，或彈出式菜單、子功\能表等，而在標題欄左邊的圖示上點擊也會彈出一個功能表，叫做系統功\能表。加速鍵實際上是功能表項的快捷鍵，應用程式常在功\能表項的右邊標出啟動這個功能表項的快捷鍵，這就是加速鍵。功\能表的結構是可嵌套的，也就是說，你可以在選擇一個功能表項時彈出另一個功\能表。菜單項的種類有正常的、被禁用的、灰化的、水準分隔線等。本節的示範程式演示了各種類型的功能表：你可以在主功\能表中看到正常的和禁用的、灰化的功能表，可以用右鍵單擊視窗的任一部分彈出一個“彈出式功\能表”，也可以看到我在系統功能表中添加了幾項新的內容。
在編程的處理中，功能表是在資源檔案中定義的（當然，你可以不用資源檔案，而在程式中用AppendMenu一項一項的添加，但使用資源檔案無疑是最簡單的辦法），然後在程式中用LoadMenu來獲得功能表控制碼再使用。在資源檔案中定義功\能表的語法如下： 菜單ID menu discardable
BEGIN
popup "主菜單項一"
BEGIN
menuitem "彈出式菜單項一", 命令ID [,OPTION]
menuitem "彈出式菜單項二", 命令ID [,OPTION]
menuitem separator
menuitem "彈出式菜單項三", 命令ID [,OPTION]
...
END
popup "主菜單項二"
BEGIN
menuitem "彈出式菜單項一", 命令ID [,OPTION]
menuitem "彈出式菜單項二", 命令ID [,OPTION]
menuitem "彈出式菜單項三", 命令ID [,OPTION]
...
popup "嵌套的菜單項"
BEGIN
menuitem "彈出式菜單項一", 命令ID [,OPTION]
menuitem "彈出式菜單項二", 命令ID [,OPTION]
menuitem "彈出式菜單項三", 命令ID [,OPTION]
...
END
END
...
END
功能表ID就是我們在程式中用LoadMenu裝入功能表用到的資源編號，menuitem separator 定義了分隔功能表項用的水平線，功\能表項定義中的option是屬性，如GRAYED是灰化的，INACTIVE是被禁用的等等。而加速鍵實際上就是定義了對應于各個功能表項的熱鍵，定義方法如下：
加速鍵ID accelerators
BEGIN
VK_F1, 對應的功能表命令ID, VIRTKEY
VK_F2, 對應的功能表命令ID, VIRTKEY
...
"A", 對應的功能表命令ID, VIRTKEY,CONTROL
"B", 對應的功能表命令ID, VIRTKEY,CONTROL
END
其中，加速鍵ID是我們在程式中用LoadAccelerator裝入加速鍵的資源編號，下面的每一項定義了一個鍵，VK_F1表示用F1，“A”表示鍵A，下面的VIRTKEY是必需的，再下面的CONTROL“或SHIFT、ALT”表示用CONTROL鍵組合，也就是說，如果你定義了："C",IDM_COPY,VIRTKEY,CONTROL 而且在功能表定義中定義了 menuitem "拷貝",IDM_COPY，那麼，你在程式中按下Ctrl-C實際上就是執行了功能表項“拷貝”。
功能表和加速鍵的編程是很簡單的，初始化的部分你需要做以下事情：
取得程式的實例控制碼(hInstance)
用LoadMenu裝入功能表，得到功\能表控制碼
用LoadAccelerator裝入加速鍵，得到加速鍵控制碼
註冊視窗類
創建視窗時在參數中制定功能表控制碼
顯示視窗
然後進入消息迴圈，在消息迴圈中用TranslateAccelerator來進行加速鍵的檢測（詳見根源程式）
當視窗顯示後，當一個功能表項或一個加速鍵被按下時，Windows向視窗過程發送WM_COMMAND消息，而當一個系統功能表中的功\能表項被按下時，Windows 向視窗過程發送WM_SYSCOMMAND，功能表項命令的ID就包括在wParam的低16位中，在一般的編程中，如果我們不對系統功能表消息進行處理，那麼只需在WM_COMMAND消息的處理中建立一段 .if/.elseif/.elseif .../.endif的語句對各個功能表命令ID進行處理就行了。
使用功能表和加速鍵的根源程式
.386
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; Programmed by 羅雲彬, bigluo@telekbird.com.cn
; Website: http://asm.yeah.net
; LuoYunBin's Win32 ASM page (羅雲彬的編程樂園)
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
.model flat, stdcall
option casemap :none ; case sensitive
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; Include 數據
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
include windows.inc
include user32.inc
include kernel32.inc
include comctl32.inc
include comdlg32.inc
include shell32.inc
include gdi32.inc
includelib user32.lib
includelib kernel32.lib
includelib comctl32.lib
includelib comdlg32.lib
includelib shell32.lib
includelib gdi32.lib
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; Equ 數據
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
IDI_MAIN equ 1000 ;icon
IDA_MAIN equ 2000 ;Accelerator
IDM_MAIN equ 4000
IDM_OPEN equ 4101
IDM_OPTION equ 4102
IDM_EXIT equ 4103
IDM_SETFONT equ 4201
IDM_SETCOLOR equ 4202
IDM_FIND equ 4203
IDM_FINDPREV equ 4204
IDM_FINDNEXT equ 4205
IDM_TOOLBAR equ 4206
IDM_TOOLBARTEXT equ 4207
IDM_INPUTBAR equ 4208
IDM_STATUSBAR equ 4209
IDM_HELP equ 4301
IDM_ABOUT equ 4302
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; 資料段
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
.data?
hIcon dd ?
hInstance dd ?
hWinMain dd ?
hMenu dd ?
hSubMenu dd ?
szBuffer db 256 dup (?)
dwFlag dd ?
;********************************************************************
; 標誌位元定義
F_TOOLBAR equ 00000001b
F_TOOLBARTEXT equ 00000010b
F_INPUTBAR equ 00000100b
F_STATUSBAR equ 00001000b
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; 資料段
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
.data
szClassName db "Menu Example",0
szCaptionMain db '菜單應用示例',0
szMenuHelp db "幫助主題(&H)",0
szMenuAbout db "關於本程式(&A)...",0
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; 代碼段
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
.code
include Debug.asm
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; 程式開始
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
start:
call _WinMain
invoke ExitProcess,NULL
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; 主視窗程式
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
_WinMain proc
local @stWcMain:WNDCLASSEX
local @stMsg:MSG
local @hAccelerator
invoke InitCommonControls
invoke GetModuleHandle,NULL
mov hInstance,eax
invoke LoadIcon,hInstance,IDI_MAIN
mov hIcon,eax
invoke LoadMenu,hInstance,IDM_MAIN
mov hMenu,eax
;*************** 註冊視窗類 *****************************************
invoke LoadCursor,0,IDC_ARROW
mov @stWcMain.hCursor,eax
mov @stWcMain.cbSize,sizeof WNDCLASSEX
mov @stWcMain.hIconSm,0
mov @stWcMain.style,CS_HREDRAW or CS_VREDRAW
mov @stWcMain.lpfnWndProc,offset WndMainProc
mov @stWcMain.cbClsExtra,0
mov @stWcMain.cbWndExtra,0
mov eax,hInstance
mov @stWcMain.hInstance,eax
mov @stWcMain.hIcon,0
mov @stWcMain.hbrBackground,COLOR_WINDOW + 1
mov @stWcMain.lpszClassName,offset szClassName
mov @stWcMain.lpszMenuName,0
invoke RegisterClassEx,addr @stWcMain
;*************** 建立輸出視窗 ***************************************
invoke CreateWindowEx,WS_EX_CLIENTEDGE,\
offset szClassName,offset szCaptionMain,\
WS_OVERLAPPEDWINDOW OR WS_VSCROLL OR WS_HSCROLL,\
100,100,550,300,\
NULL,hMenu,hInstance,NULL
invoke ShowWindow,hWinMain,SW_SHOWNORMAL
invoke UpdateWindow,hWinMain
;*************** 消息迴圈 *******************************************
invoke LoadAccelerators,hInstance,IDA_MAIN
mov @hAccelerator,eax
.while TRUE
invoke GetMessage,addr @stMsg,NULL,0,0
.break .if eax == 0
invoke TranslateAccelerator,hWinMain,@hAccelerator,addr @stMsg
.if eax == 0
invoke TranslateMessage,addr @stMsg
invoke DispatchMessage,addr @stMsg
.endif
.endw
ret
_WinMain endp
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
WndMainProc proc uses ebx edi esi, \
hWnd WORD,uMsgWORD,wParamWORD,lParam:DWORD
local @stPos OINT
mov eax,uMsg
.if eax == WM_CREATE
mov eax,hWnd
mov hWinMain,eax
call _Init
;********************************************************************
.elseif eax == WM_COMMAND
.if lParam == 0
mov eax,wParam
movzx eax,ax
.if eax == IDM_EXIT
call _Quit
.elseif eax == IDM_TOOLBAR
xor dwFlag,F_TOOLBAR
call _MenuStatus
.elseif eax == IDM_TOOLBARTEXT
xor dwFlag,F_TOOLBARTEXT
call _MenuStatus
.elseif eax == IDM_INPUTBAR
xor dwFlag,F_INPUTBAR
call _MenuStatus
.elseif eax == IDM_STATUSBAR
xor dwFlag,F_STATUSBAR
call _MenuStatus
.else
_Debug "功能表命令\","命令ID",eax
.endif
.endif
;********************************************************************
.elseif eax == WM_SYSCOMMAND
mov eax,wParam
movzx eax,ax
.if eax == IDM_HELP || eax == IDM_ABOUT
_Debug "功能表命令\","命令ID",eax
.else
invoke DefWindowProc,hWnd,uMsg,wParam,lParam
ret
.endif
;********************************************************************
; 按下右鍵時彈出一個POPUP功能表
;********************************************************************
.elseif eax == WM_RBUTTONDOWN
invoke GetCursorPos,addr @stPos
invoke TrackPopupMenu,hSubMenu,TPM_LEFTALIGN,@stPos.x,@stPos.y,NULL,hWnd,NULL
;********************************************************************
.elseif eax == WM_CLOSE
call _Quit
;********************************************************************
.else
invoke DefWindowProc,hWnd,uMsg,wParam,lParam
ret
.endif
;********************************************************************
; 注意：WndProc 處理 Windows 消息後，必須在 Eax 中返回 0
; 但是由 DefWindowProc 處理後的返回值不能改變，否則視窗
; 將無法顯示!
;********************************************************************
xor eax,eax
ret
WndMainProc endp
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; 主視窗控制副程式
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
_Init proc
local @hSysMenu
invoke SendMessage,hWinMain,WM_SETICON,ICON_SMALL,hIcon
;********************************************************************
; POPUP功能表要用到子功\能表才能實現
;********************************************************************
invoke GetSubMenu,hMenu,1
mov hSubMenu,eax
call _MenuStatus
;********************************************************************
; 在系統功能表中添加功\能表項
;********************************************************************
invoke GetSystemMenu,hWinMain,FALSE
mov @hSysMenu,eax
invoke AppendMenu,@hSysMenu,MF_SEPARATOR,0,NULL
invoke AppendMenu,@hSysMenu,MF_STRING,IDM_HELP,offset szMenuHelp
invoke AppendMenu,@hSysMenu,MF_STRING,IDM_ABOUT,offset szMenuAbout
ret
_Init endp
;********************************************************************
; 根據標誌位元設置相應功能表項的狀態
;********************************************************************
_MenuStatus proc
test dwFlag,F_INPUTBAR
.if ZERO?
invoke CheckMenuItem,hMenu,IDM_INPUTBAR,MF_UNCHECKED
.else
invoke CheckMenuItem,hMenu,IDM_INPUTBAR,MF_CHECKED
.endif
test dwFlag,F_TOOLBAR
.if ZERO?
invoke CheckMenuItem,hMenu,IDM_TOOLBAR,MF_UNCHECKED
.else
invoke CheckMenuItem,hMenu,IDM_TOOLBAR,MF_CHECKED
.endif
test dwFlag,F_TOOLBARTEXT
.if ZERO?
invoke CheckMenuItem,hMenu,IDM_TOOLBARTEXT,MF_UNCHECKED
.else
invoke CheckMenuItem,hMenu,IDM_TOOLBARTEXT,MF_CHECKED
.endif
test dwFlag,F_STATUSBAR
.if ZERO?
invoke CheckMenuItem,hMenu,IDM_STATUSBAR,MF_UNCHECKED
.else
invoke CheckMenuItem,hMenu,IDM_STATUSBAR,MF_CHECKED
.endif
ret
_MenuStatus endp
;********************************************************************
_Quit proc
invoke DestroyWindow,hWinMain
invoke PostQuitMessage,NULL
ret
_Quit endp
;********************************************************************
end start
程式的分析
讓我們來簡單分析一下這個程式，首先這個程式和上一節的最簡單的視窗程式的不同之處就是消息迴圈，如下：
.while TRUE
invoke GetMessage,addr @stMsg,NULL,0,0
.break .if eax == 0
invoke TranslateAccelerator,hWinMain,@hAccelerator,addr @stMsg
.if eax == 0
invoke TranslateMessage,addr @stMsg
invoke DispatchMessage,addr @stMsg
.endif
.endw
在迴圈中的TranslateAccelerator用來確定存放在MSG結構中的消息是不是鍵盤消息，如果是，它查找控制碼@hAccelerator對應的加速鍵表，如果找到了一個匹配項，那麼它將用命令ID向視窗發送WM_COMMAND消息，同時返回非0值，這時候表示消息已經被處理，不用再調用下面的TranslateMessage 和 DispatchMessage 了，如果不是，那麼它將返回0，消息迴圈繼續。
另外，要說明的是彈出式功能表，在程式中我們回應WM_RBUTTONDOWN消息對按下右鍵進行處理， 然後調用GetCursorPos取得當前滑鼠座標，然後使用TrackPopupMenu在滑鼠位置上彈出一個功能表，但是在資源檔案中，“彈出式功\能表”是無法直接定義的，所以在初始化部分，我們使用GetSubMenu 取出彈出式子功能表的控制碼供TrackPopupMenu使用。
實用相關搜尋: map nds bus lg car she it pda model 水
|
〓中國黑客聯盟（CHU）〓前核心成員，現為榮譽會員
〓中國黑客聯盟（CHU）〓網絡電子雜誌《矩陣》編輯
風堂技術工作室
|
|
|
|
設為首頁
加入收藏
